Lesson: The easy way to fly from A to B

Descibes for a beginner how to fly from A to B with FS(X)P and a FS fixed winged aircraft

Good morning !

We want to explain today step by step the easy way to fly from airport A (let's say Frankfurt, Germany) to airport B (let's say EGLL, London Heathrow, UK) with FS2004 and FSP.

Please start your flight simulator.
In the launch panel, please 'create flight' and select an aircraft first (let us use the standard FS Boeing 737).
Use the FS2004 flight planner to define the departure airport (EDDF, active runway) and destination airport (Heathrow, EGLL) as well as the waypoints. Select 'IFR flight' and high altitude airways. Generate the waypoints and save the resulting FS2004 flight file to disk (this is in PLN format).

Start the flight.

You will be on the active runway in Frankfurt.

Open the FSP AP panel.
Import the flight 'IFR_Frankfurt_London' by selecting 'Import flightplan' from FSP menu.
Add the standard takeoff and landing routines for fixed winged aircraft by pressing 'yes' in the dialog box that is displayed after the import.
Save the imported flightplan to FSP format by selecting 'Save as FSP flightplan' to the directory where all FSP flightplans are stored ($fs2004homedir\fspilot\flightplans). The name of the flightplan will be EDDF_EGLL.txt. This file can be opened later with a conventional text editor.

Select 'Run flightplan'.
The aircraft will operate lights, flaps, takeoff and begin to fly the waypoints to Heathrow. Flaps and gear will be retracted.
You can modify the speed, climb rate, target altitudes at any time during the flight. During the flight, you can use time acceleration. The EFIS displays, on the bottom, the distance from EDFF and to EGLL as well as the time you will need to reach destination. 100 nm inbound Heathrow, the jet will select the best runway according to surface wind and runway length. Two additional waypoints will be generated (approach entry and ILS entry), and the jet will automatically fly the approach. On the ILS (instrument landing system), flaps will be set and gear will be operated. Autolanding.

If you want to fly this route again later, you only need to place the jet at EDDF on active runway and 'Open flightplan' (EDDF_EGLL.txt). Select 'Run flightplan' from FSP menu.

Thanks for flying FS(X)P today.


------------------------------------------------------------------

Now, what is in the flightplan EDDF_EGLL.txt ?

Here we have the text, with some comments ( -> //) :

// -----------------------------------------------------------
// Flightplan for FS200x
// for use with FSPilot
//
// FSPilot (c) 2006 by Scientific Networks Munich
// -----------------------------------------------------------
// add your comment here
// and here
//
//
set speedunits knots
set distanceunits miles
set apcontrol plane
// enable the user to modify speeds, climb, altitudes
set userinput on
// set altitude to 26000 ft
set alt 26000.0
// set climb to 1500 ft/min
set climb 1500.
landinglights on
navlights on
// flaps notch 1 for takeoff
flaps 1
// head current heading
// if you need to depart from a different runway,
// enter 'head ch' (head current heading) instead of 'head 250.8' here
head 250.8
run speed 200.
maintain speed
run apv
wait altclimb 563.8
gear up
flaps 0
landinglights off
set speed 250.
set origin EDDF
set destination EGLL
// this are the waypoints
// If you want to design new plans:
// giving the coordinates is not mandatory.
// waypoint 26000.0 220. NTM would also work as long as NTM is in the AIRAC
waypoint 26000.0 220. NTM 50.01583333 6.53183333
waypoint 26000.0 220. SPI28 50.21666667 6.18333333
waypoint 26000.0 220. LARED 50.41916666 5.79883334
waypoint 26000.0 220. SPI 50.51466665 5.62333336
waypoint 26000.0 220. NUVIL 50.53533332 5.52383334
waypoint 26000.0 220. REMBA 50.66216666 4.91416664
waypoint 26000.0 220. KOK 51.09466666 2.65166664
waypoint 26000.0 220. KONAN 51.13083333 2.00000000
waypoint 26000.0 220. DVR 51.16250000 1.35916665
find bestrunway EGLL
select approachentry
flaps 2.
set speed 240.
wait distin 2.
select ilsentry
wait distin 1.
gear down
landinglights on
select bestrunway
set speed 200.
set ils
// wait until groundcontact
// operate brakes and retrothrust
// and wait unless speed is below 30 kts
wait speedless 30.
stop aph
stop apv
flaps 0.
wait speedless 5.
throttle zero
end